Internet de les coses amb ESP32 i ESP8266

Exemples Referència Plaques   Recursos CITCEA
Projectes Programació Perifèrics   Inici

Controlem el color d'un NeoPixel enviant tres valors enters

En aquest exemple tindrem un NeoPixel connectat a la pota 1.

La pàgina que veurà l'usuari tindrà el següent contingut (vegeu les etiquetes del llenguatge html).

<!DOCTYPE HTML>
<meta charset='UTF-8'>
<html>
<h1>El LED està a (0, 0, 0)</h1>
<form action='/' method='get'>
<p></p>
<p>R</p>
<input type='range' name='R' min='0' max='255' value='0'>
<p></p>
<p>G</p>
<input type='range' name='G' min='0' max='255' value='0'>
<p></p>
<p>B</p>
<input type='range' name='B' min='0' max='255' value='0'>
<p></p>
<p></p>
<input type='submit'>
</form>
</html>

Que ens donarà una pàgina similar a aquesta:

Pàgina web

El programa connecta el microcontrolador a un punt d'accés existent (del que hem de saber l'identificador i la contrasenya), escriu al monitor sèrie la seva adreça IP i es queda a l'espera que algun usuari s'hi connecti. Quan ho fa, li envia la pàgina html en la que l'estat del NeoPixel es personalitza segons com estigui en aquell moment. Quan es prem el botó es torna a carregar la pàgina afegint el paràmetre corresponent. Les opcions són l'adreça sense paràmetres o amb tres valors entre 0 i 255.

aaa.bbb.ccc.ddd/
aaa.bbb.ccc.ddd/?R=255&G=63&B=127

El programa d'aquest exemple és el següent:

// Aquest programa està parcialment basat en els exemples de la pàgina
// https://www.arduino.cc/en/Tutorial/LibraryExamples#wifi1010
#include <SPI.h>    // Carreguem la biblioteca SPI
#include <WiFiNINA.h>    // Carreguem la biblioteca WiFiNINA
#include <Adafruit_NeoPixel.h>
#define LED 1    // pota on hem connectat el LED
const char idXarxa[] = "xarxa-wifi";    // Nom del punt d'accés 
const char contrasenya[] = "contrasenya-wifi";    // Contrasenya de connexió 
byte R = 0;    // Color vermell
byte G = 0;    // Color verd
byte B = 0;    // Color blau
bool enviar = false;
int status = WL_IDLE_STATUS;
WiFiServer server(80);    // Creem un objecte de comunicació amb el port 80
                          // El port 80 és el de defecte per a http
Adafruit_NeoPixel cadena = Adafruit_NeoPixel(1, LED, NEO_GRB + NEO_KHZ800);
String Dades(String peti, String param){
    String valor = "";
    String sepa;
    int pos;
    if (peti.indexOf("?") != -1) {    // Si no ho troba torna -1
        peti = peti.substring(peti.indexOf("?")+1);
        if (peti.indexOf(param) != -1) {    // Si no ho troba torna -1
            peti = peti.substring(peti.indexOf(param)+param.length());
            sepa = peti.substring(0, 1);
            peti = peti.substring(1);
            pos = peti.indexOf("&");
            if (pos == -1) {
                pos = peti.indexOf(" ");
            }
            if ((pos != 0) && (sepa == "=")){
                valor = peti.substring(0, pos);
            }
        } 
    }
    return valor;
}
void setup() {    // Inicialització
    Serial.begin(9600);    // Monitor sèrie
    cadena.begin();  // Inicialitza els NeoPixels				
    cadena.show();
    if (WiFi.status() == WL_NO_MODULE) {
        Serial.println("No s'ha trobat el dispositiu Wi-Fi");
        while (true);    // Bloquegem el programa
    }
    String versio = WiFi.firmwareVersion();
    if (versio < "1.0.0") {
        Serial.println("Convindria actualitzar el firmware");
    }
    while (status != WL_CONNECTED) {
        Serial.print("Connectant a la xarxa ");
        Serial.println(idXarxa);
        status = WiFi.begin(idXarxa, contrasenya);
        delay(10000);    // Ho tornarem a intentar passats 10 s
    }
    server.begin();    // Posem en marxa el servidor
    Serial.print("Connectat a "); 
    Serial.println(WiFi.SSID());
    Serial.print("Estat de la connexió: ");
    Serial.println(WiFi.status()); 
    Serial.print("Adreça IP del dispositiu: ");
    Serial.println(WiFi.localIP()); 
    Serial.print("Intensitat del senyal: ");
    Serial.print(WiFi.RSSI()); 
    Serial.println(" dBm");
    Serial.println(); 
    Serial.print("Ja pots fer la teva connexió al dispositiu ");
    Serial.println(WiFi.localIP()); 
}
void loop() {    // Programa que es repeteix indefinidament
    if (status != WiFi.status()) {    // Mirem si ha canviat l'estat de la connexió
        status = WiFi.status();
        if (status == WL_AP_CONNECTED) {
            Serial.println("Dispositiu connectat al punt d'accés");
        } else {
            Serial.println("El dispositiu s'ha desconnectat del punt d'accés");
        }
    }
    WiFiClient client = server.available();    // Mirem si hi ha clients
    if (client) {                             // Si hi ha un client...
        Serial.println("Nou client");
        String peticio = "";                // Aquí guardarem una línia de la petició del client
        while (client.connected()) {            // Mentre el client estigui connectat
            if (client.available()) {             // Si hi ha dades disponibles
                char c = client.read();             // Llegim un byte
                Serial.write(c);
                if (c == '\n') {                    // Mirem si és un salt de línia
                    // Si hem rebut una línia buida vol dir que tenim dos salts de línia seguits
                    // vol dir que ha acabat la petició del client i enviem la resposta:
                    if (peticio.length() == 0) {
                        enviar = true;    // Llestos per enviar la resposta
                        break;    // Sortim del while
                    } else {      // Si hem rebut un salt de línia
                        // Ha acabat una línia de la petició, anem a veure si és la que ens interessa
                        // Rebrem un munt de línies però només hem d'analitzar la que comença per GET
                        if (peticio.indexOf("GET") != -1) {    // Si no ho troba torna -1
                            // Ara cal comprovar si s'ha demanat una acció sobre el LED
                            if (Dades(peticio, "R") != "") {    // Hi havia el paràmetre R?
                                R = Dades(peticio, "R").toInt();
                            } 
                            if (Dades(peticio, "G") != "") {    // Hi havia el paràmetre G?
                                G = Dades(peticio, "G").toInt();
                            } 
                            if (Dades(peticio, "B") != "") {    // Hi havia el paràmetre B?
                                B = Dades(peticio, "B").toInt();
                            } 
                            cadena.setPixelColor(0, R, G, B);
                            cadena.show();
                        }
                        peticio = "";    // Comencem línia amb una línia buida
                    }
                } else if (c != '\r') {    // Si el caràcter no és un retorn
                    peticio += c;      // Afegim el caràcter rebut
                }
            }
        }
        if (enviar) {
            // Resposta al client
            client.println("HTTP/1.1 200 OK");
            client.println();    // Imprescindible línia en blanc
            client.println("<!DOCTYPE HTML>");
            client.println("<meta charset='UTF-8'>");
            client.println("<html>");
            // En el títol l'estat del LED
            client.print("<h1>El LED està a (");                 
            client.print(R);  
            client.print(", ");  
            client.print(G);  
            client.print(", ");  
            client.print(B);  
            client.println(")</h1>");
            client.println("<form action='/' method='get'>");
            client.println("<p></p>");
            client.println("<p>R</p>");
            client.print("<input type='range' name='R' min='0' max='255' value='");
            client.print(R);
            client.println("'>");
            client.println("<p></p>");
            client.println("<p>G</p>");
            client.print("<input type='range' name='G' min='0' max='255' value='");
            client.print(G);
            client.println("'>");
            client.println("<p></p>");
            client.println("<p>B</p>");
            client.print("<input type='range' name='B' min='0' max='255' value='");
            client.print(B);
            client.println("'>");
            client.println("<p></p>");
            client.println("<p></p>");
            client.println("<input type='submit'>");
            client.println("</form>");
            client.println("</html>"); 
            delay(1);
            enviar = false;
        }
        client.stop();    // Tanquem la connexió
        Serial.println("Fi de la connexió amb el client");
    }
}

El nostre programa de prova escriu unes quantes coses al monitor sèrie (instruccions Serial.print i Serial.println). Quan ja tinguem clar que el programa funciona, les podem eliminar quasi totes i probablement anirà una mica més ràpid.

 

 

 

 

 

 

 

 

 

 

Llicència de Creative Commons
Aquesta obra d'Oriol Boix està llicenciada sota una llicència no importada Reconeixement-NoComercial-SenseObraDerivada 3.0.